freqrcpt.bat
Generated on Tue Dec 05 17:44:03 Eastern Standard Time 2006 from freqrcpt.bat
@echo off
title FREQRCPT: Parse through all the GW POA log files for Recipients
echo FREQRCPT: Parse through all the GW POA log files for Recipients
echo Date : 1 April 2005
echo Author : Bob Jonkman [bjonkman@sobac.com]
echo.
if "%1"=="/h" goto help
if "%1"=="/H" goto help
if "%1"=="-h" goto help
if "%1"=="-H" goto help
if "%1"=="/?" goto help
if "%1"=="AlertOnly" goto alert
if "%1"=="HTMLOnly" goto html
goto begin
:help
echo Parameters: %1 - Date pattern, like 'mmdd' (optional)
echo %2 - Postoffice (optional)
echo.
echo Usage : FREQRCPT [mmdd [postoffice]]
echo.
echo Default date is ???? (all dates)
echo.
goto end
:begin
set THRESHOLD=100
set searchpattern=Distributed:
set freqrcpttempfile=freqrcpt.tmp
rem "Now" is the end of the time window....
set TIMEEND=%time%
echo %TIMEEND%
set datepattern=%1
if "%datepattern%"=="" set datepattern=????
rem reset log file
if exist %freqrcpttempfile% del %freqrcpttempfile%
echo Searching for "%searchpattern%" in %datepattern%POA.*
rem Parameters: PARSEPOA parsestring outputfile [mmdd [postoffice]]
call parsepoa %searchpattern% %freqrcpttempfile% %datepattern% %2
:parse
echo Preserving old threshold data...
if exist freqrcpt-threshold-old.csv del freqrcpt-threshold-old.csv
if exist freqrcpt-threshold.csv ren freqrcpt-threshold.csv freqrcpt-threshold-old.csv
if not exist freqrcpt-threshold-old.csv copy crlf.txt freqrcpt-threshold-old.csv
echo Generating CSV files...
gawk -f freqrcpt.awk -f library.awk -v TRW=%THRESHOLD% -v "TIMEEND=%TIMEEND%" %freqrcpttempfile% > rcpt-%date%.csv
gawk -f xtab.awk -f library.awk -v TIMESLOT=1 -v YFIELDNAME=Datetime -v XFIELDNAME=Source %freqrcpttempfile% > xtab-timexsource.csv
copy rcpt-%date%.csv rcpt.csv
:html
echo Generating HTML file...
gawk -f csv2html.awk -f library.awk -v TITLE="GW Frequent Recipients %DATE% %TIME%" freqrcpt-alert.csv freqrcpt-threshold.csv freqrcpt-threshold-old.csv freqrcpt-exclude.txt xtab-timexsource.csv > freq-rcpt.html
gawk -f csv2html.awk -f library.awk -v TITLE="GW Recipients %DATE% %TIME%" -v LINK=1 rcpt.csv > rcpt.html
copy *.html \\cotgw506\sys\apache2\htdocs\stats\
if "%1"=="HTMLOnly" goto end
copy rcpt.csv \\cotgw506\sys\apache2\htdocs\stats\
:alert
echo Generating alert...
if exist freqrcpt.101 del freqrcpt.101
gawk -f alert.awk -f library.awk -v THRESHOLD=%THRESHOLD% -v COMP=GT -v TO=gwmon@w01431.corp.example.com -v SUBJECT="GWAlert: Frequent Recipient" -v ALERTFILE=freqrcpt.101 freqrcpt-alert.csv
if exist freqrcpt.101 copy freqrcpt.101 c:\mercury\queue
if exist freqrcpt.101 del freqrcpt.101
set PO=
set datepattern=
set searchpattern=
set freqrcpttempfile=
:end
echo %time%
rem EOF: FREQRCPT.BAT
1 files processed.